clear;
 fs = 5000; // frequence d'echantillonnage
 // fs = 1000; // lors des tests
 duree=4; // duree de l'air en secondes
 n=216; // nombre total de marches (18 marches par demi-ton : 1/4 comma)
 raison = 2^(1/n); // les notes suivent une suite geometrique
 // afin de doubler la frequence a la fin
 
 N = round(duree*fs/n); // nombre de pas par marche
 
 f=264; // do3
 // f=50; // lors des tests
 son(1)=0;
 
 for i=0:n-1
    decalage=i*N;
    // raccordement entre les marches
    if i==0 then
       phase=0;
    else
       valeur_penultieme=son(decalage-1);
       valeur_precedente=son(decalage);
       phase=asin(valeur_precedente);
       signe=valeur_precedente-valeur_penultieme;
       if signe < 0 then
          if valeur_precedente < 0 then
             phase = -%pi-phase;
             else phase = %pi-phase;
          end
       end
    end
    for j=1:N
       instant=j/fs;
       son(decalage+j) = sin(2*%pi*instant*f+phase);
    end
       f = f*raison;
 end
 
 // terminer en decrescendo
 taille = max(size(son));
 valeur_penultieme=son(taille-1);
 valeur_precedente=son(taille);
 phase=asin(valeur_precedente)+1/fs;
 signe=valeur_precedente-valeur_penultieme;
 if signe < 0 then
    if valeur_precedente < 0 then
       phase = -%pi-phase;
       else phase = %pi-phase;
    end
 end
 demi_seconde = round(fs/2);
 for i=0:demi_seconde-1
    instant = i/fs;
    son(i+taille)=sin(2*%pi*instant*f+phase)*(1-i/demi_seconde);
 end
 
 // plot(son') // lors des tests
 
 savewave('progression_continue_octave_do3_do4.wav', son', fs)
 
 // wavwrite(son', fs, 'progression_continue_octave_do3_do4') // alternative